crdonk3's Maps

[Asbestos]

Yup.
Maps
Creeper World (FINISHED) - smatter.cw3 - Looking for: N/A
Rocky Road (FINISHED) - degradation.cw3 - Looking for: N/A
Causeway (FINISHED) - causeway.cw3 - Looking for: N/A

[planetfall]

The volcanoes make a very annoying noise. It's pretty easy to make a fake spore with CRPL that doesn't play sounds (or has a less obnoxious one.)

Edit: also, I'm here and don't know how to progress. I'm trying to save the anticreeper tank things because I assume they're one use only.

[Asbestos]

Smatter Changelog
- Replaced Forge with AC tank, made Forge much cheaper
- Smoothened out some terrain for more places to build
- Added AC runner nest
- Added a few AC tanks
- Removed Forge message
- Didn't do anything to the volcanoes, because I don't know how to make CRPL spores
- Removed Herobrine (not that he was there in the first place)

[planetfall]

K, here's a spore script, complete with pretty shadow and everything!

Code Select Expand


# Spore.crpl
# Created on: 11/30/2014 10:10:31 AM
# ------------------------------------------

$targetx:-1
$targety:-1
$Payload:50

$Image:"Custom0_256"

once
"Weapons15" PlaySound
Self "main" <-Image SetImage
Self "shadow" <-Image SetImage
Self "main" -1 SetImagePositionZ
Self "shadow" -0.05 SetImagePositionZ
<-targetx <-targety 1.5 QueueMove
<-targetx <-targety CellToPixel ->targety ->targetx #Precision!
CurrentPixelCoords <-targetx <-targety Distance 24 div 10 max 30 min ->MaxArc
CurrentPixelCoords <-targetx <-targety Distance ->TotalDist
endonce

GetQueuedMoveCount eq0 if
1 ->landed
# "Misc13" PlaySound
CurrentCoords <-Payload AddCreeper
Self 0 Destroy
else
CurrentPixelCoords <-targetx <-targety Distance <-TotalDist div ->Progress
<-Progress 0.5 sub <-MaxArc mul 2 pow neg <-MaxArc 2 mul add 0.06 max ->z
Self "main" 0 <-z 2.0 div <-z neg SetImagePosition
<-z 2.0 div SetTargetOffsetY
Self "shadow" <-z 4.0 div SetImagePositionX
Self "shadow" 0 0 0 30.0 <-z sub 8 mul SetImageColor
<-dummy 0.017 add ->dummy
Self "main" <-dummy SetImageRotation
Self "shadow" <-dummy SetImageRotation
endif

:destroyed
<-landed not if
4 CurrentPixelCoords <-z 2.0 div add <-z neg 1 1 0.03 CreateEffect
"SporeExplosion" PlaySound
endif

:awake
Self CONST_NULLIFIERDAMAGES 0 SetUnitAttribute
Self CONST_TAKEMAPSPACE 0 SetUnitAttribute
Self CONST_CREATEPZ 0 SetUnitAttribute
Self CONST_SUPPORTSDIGITALIS 0 SetUnitAttribute
Self CONST_BEAMTARGET 1 SetUnitAttribute
Self CONST_DESTROYMODE 0 SetUnitAttribute


And the volcano script modified to spawn it:

Code Select Expand


# Volcano (no coning).crpl
# Created on: 11/2/2014 6:48:39 PM
# ------------------------------------------
# volcano.crpl
# Created on: 2/9/2014 2:13:15 PM
# Created by: First
# Defaults produce a fairly mild volcano that grows a cone and emits spore bombs
# ConeGrowthIntervalFrames is in game-frames
# SporeIntervalSeconds is in game-seconds
# ConeSize is a radius
# WTB: a better, more realistic looking cone growth algorithm
# WTB: <-xCurrent <-yCurrent <-Height GetNearestTerrain ->xNearest ->yNearest
#    Gets the location of nearest terrain that has height of Height
# WTB: cool looking crater image to replace the tower image
# ------------------------------------------
$SporeIntervalSeconds:0.20
$SporeRange:20
$SporePayload:100

once
<-SporeIntervalSeconds 30 mul <-SporeIntervalSeconds 30 mul 2 mul RandInt SetTimer1
endonce

GetTimer1 eq0 if
CurrentCoords <-SporeRange RandCoordsInRange ->yTar ->xTar
# CurrentCoords <-xTar <-yTar 1.0 <-SporePayload CreateSpore
"CRPLCORE" CurrentCoords CreateUnit ->spore
<-spore "Spore.crpl" AddScriptToUnit
<-spore "Spore.crpl" "targetx" <-xTar SetScriptVar
<-spore "Spore.crpl" "targety" <-yTar SetScriptVar
<-spore "Spore.crpl" "Payload" <-SporePayload SetScriptVar
<-SporeIntervalSeconds 30 mul SetTimer1
endif


[Asbestos]

It's not working. The volcanoes don't produce any spores, and when I put the spore script into them they disappear.

[planetfall]

Huh. It works for me... Try this.

[Asbestos]

Er, while you were doing that I posted the map to CS before I saw your post. Sorry.

[Asbestos]

New map is up.

[Asbestos]

Degradation Changelog
- Added AC runner nest
- Changed addmitters slightly
- Increased initial scout spawner delay
- Added ore near the start
- Increased energy packet near start

[Asbestos]

Degradation Changelog
- Made scout spawners a lot slower
- Added wall around initial planet
- Halved scout payloads

[warren]

The answer to question 3 is: yes, in: 22:34.7. Hard start. That could be a good thing from certain perspectives. Easy finish. Hard start and easy finish do not go together well. It took quite a while to get the energy production up. But once I did, the map annoyingly took forever because there was nowhere to build. I am fine with maps where it takes a while to terp to victory, but not if defeating creeper so easily outpaces terping. Or if there is nothing else to do while waiting. Those saucers were way to slow. They were so slow, they were not even really a problem in the early game. In the end game they were a joke. I recommend adding a building time and upping the creation frequency. And adding hover text so users know when the saucers are coming. I would also vastly increase the creeper on the last two islands. But not the first emitter on the last island. That one was okay. Maybe add another emitter to the big last island, behind that caged one so it is harder to sneak behind and takes a bit more work to get that last mile.

Edit:
I forgot to mention all the good stuff. The digitalis was perfect. The digitalis in the endgame was hardly a problem. It did slow progress, but I could always position blasters somewhere to deal with it. In the early game, It was an interesting nuisance. I could only squeeze one energy upgrade out of the totems before the creeper took the island from me. I used guppys to get another energy upgrade, but it took quite a while to finally cut off that digitalis tendril.

That early runners nest posed a fascinating challenge. I would not call it a hard challenge, by that time my energy was building and I had essentially already won. I almost never use snipers, but that nest asked everything from me. If you cut the map in half, removed the middle two islands, Just leaving the first two and last two, I would say you created the perfect map.

I would recommend that you add a sound effect when saucers are launched. They occasionally did take buildings from me, because I did not see or hear them coming.

[Asbestos]

Degradation Changelog
- Added addmitter at last island
- Broke up middle two islands(?) into smaller islands
- Added two more digitalis tendrils at the end
- Added spore attacks at 7 and 11.5 (or so) minutes
- Added sounds to scout spawners
- Added and messed up popup text to addmitters and scout spawners
- Put a little extra space on the ore island
- Put a little extra space on the third(?) island
- Sped up scout spawners

[warren]

Oof! I see you're using Delay. That means you can't have a cool countdown effect. But this code should work:

Code Select Expand


<-MinInitDelay1 <-MaxInitDelay2 RandInt ->temp
"Interval: " <-temp concat SetPopupText
<-temp Delay


And for the emitters:

Code Select Expand


"Amt:" <-CreeperAmount concat "
Interval:" concat <-Delay concat SetPopupText


I don't think you necessarily need popup text on everything, just the flying saucer makers. Note that the "" are only around the english words. Note the use of concat. That is how you add code to text. Note the use of a temp variable. That is because RandInt returns a different value on each use.

Edit: I hope you didn't delete parts of the middle only because of my comments. I meant to say that the end was perfect if a lot too easy and the beginning was perfect, if a little too hard, and the middle was boring. Simply deleting the middle is only one possible solution.

Edit: Although I have to say it looks cooler now. I may have to test it again later.

[Asbestos]

For some reason the spores aren't firing.

Code Select Expand

# spore attack.crpl
# Created on: 3/3/2015 6:40:07 AM
# ------------------------------------------

once
12600 Delay
# 7 minutes
ClearConversation
1 "Spore attack incoming in 2 minutes." AddConversationMessage
0 "Huh? Where is it coming from?" AddConversationMessage
1 "A battery of spore towers all the way on the east side of the planet. They're too far away to bother attacking." AddConversationMessage
1 "Fortunately, that means the spore towers will expend all of their energy launching the spores at us and will no longer be able to fire." AddConversationMessage
ShowConversation
PauseGame
3600 Delay
ClearConversation
1 "Three spores are inbound." AddConversationMessage
ShowConversation
PauseGame
10 Delay
"Misc19" PlaySound
99 44 71 RandInt RandUnitCoords 1 40 CreateSpore
15 Delay
99 44 71 RandInt RandUnitCoords 1 40 CreateSpore
15 Delay
99 44 71 RandInt RandUnitCoords 1 40 CreateSpore
10800 Delay
# 15 minutes, 6 minutes from last attack
ClearConversation
1 "Spore attack incoming in 1.5 minutes." AddConversationMessage
0 "Wait, you said that those spore towers couldn't fire anymore." AddConversationMessage
1 "This is a different battery of spore towers, firing from the west this time." AddConversationMessage
1 "Again, they will not be able to create spores after this attack." AddConversationMessage
ShowConversation
PauseGame
2700 Delay
ClearConversation
1 "Five spores are inbound." AddConversationMessage
ShowConversation
PauseGame
10 Delay
"Misc19" PlaySound
0 15 41 RandInt RandUnitCoords 1 40 CreateSpore
30 Delay
0 15 41 RandInt RandUnitCoords 1 40 CreateSpore
0 15 41 RandInt RandUnitCoords 1 40 CreateSpore
30 Delay
0 15 41 RandInt RandUnitCoords 1 40 CreateSpore
0 15 41 RandInt RandUnitCoords 1 40 CreateSpore
17100 Delay
# 26 minutes, 9.5 minutes from last attack
ClearConversation
1 "A large asteroid is passing by amount four light-seconds from here. Also, spore attack incoming in 3 minutes." AddConversationMessage
0 "Sweet baby fudge cakes on high, where are all these spores coming from?!" AddConversationMessage
1 "I don't know. There are no more long-range spore towers in this system..." AddConversationMessage
1 "Wait. The asteroid is full of them. Maybe it's even made out of them. It is made out of them. Geez." AddConversationMessage
1 "I can shoot down most of the spores before they even get near the space we're clearing out, but there will still be plenty." AddConversationMessage
1 "Just so you know, they'll be coming from the north from the Command Nodes' perspective." AddConversationMessage
ShowConversation
PauseGame
5400 Delay
ClearConversation
1 "Twenty spores are inbound." AddConversationMessage
0 "Oh my." AddConversationMessage
ShowConversation
PauseGame
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
90 Delay
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
90 Delay
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
90 Delay
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
0 99 RandInt 0 RandUnitCoords 1 20 CreateSpore
1800 Delay
ClearConversation
0 "Is that it? Are we done with all those stupid spores?" AddConversationMessage
1 "That was nineteen..." AddConversationMessage
ShowConversation
PauseGame
30 Delay
"Misc19" PlaySound
0 99 RandInt 0 37 25 155 1000 CreateSpore
endonce

[warren]

Which core did you put that script on?