[MAP in Progress] See how i make an Image Map [Image Map 4]

[FOXX]

Changed it in the script, now it compiles ok.
But the Enemy Stunners don't get smaller or get destroyed.
I've set the KillTimePerStunner value from 1 to 100 but doesn't seem to have an effect.

In this line:
once <-KillTimePerStunner 30 mul -1 pow ->Damage endonce
I've changed the -1 to -2 and -5 -> also no change in effect.


And what do you think about the last land layout?   More land - Less Land or ok enough?

Edit -> The GM1 [for dealing with the Enemy Stunners, has to be small because it needs to fit in small places]
             For now i'm not thinking about adding more ships. Not even a Lathe Ship [except the HQ] so all has to be Lathe with Omnis.

GM1

[close]

[FOXX]

Update 6-10-2017 [in Main Post]

Added - New Ideas
Added - New Land Layout
Added - Start Conversation
Added - Scripts

GM -> Could you look at the Discharge Script for the Phantom Coil so i can test with this.

[GoodMorning]

Here's a working script.

The problem was that the Stunners have UnitType set to "Stunner(Clone)".

Code Select Expand

# --Discharger-- 6/11/2017 9:23:48 AM
$Range:40
$KillTimePerStunner:5

once
<-KillTimePerStunner 30 mul -1 pow ->Damage
#"DMG:" <-Damage Trace2
endonce

CurrentCoords <-Range 0 GetAllUnitsInRange ->Units
#<-Units Trace

0 ->Index
while <-Units GetListCount <-Index gt repeat
<-Units[<-Index] ->UID
<-UID GetUnitType dup "Stunner" eq swap "Stunner(Clone)" eq or if
<-Index 1 add ->Index
else
<-Units <-Index RemoveListElement
endif
endwhile

#<-Units Trace

<-Damage <-Units GetListCount div ->SpreadDamage
<-Units GetListCount 0 do
<-Units[ I ] dup GetUnitHealth <-SpreadDamage sub SetUnitHealth
loop

[FOXX]

Yep :)
That does the job!
Comparing the Scripts i think there was no way i could have done that.
I understand what the issue was but the solution is another thing.
Thanks GM -> I can proceed.

[GoodMorning]

It's not that complex, just a matter of trying one thing and another. The way I did it was:

Debugging thoughts

Think: Hmm, not hitting targets... Does it have any?
Try: Trace target list.
Observe: Empty. So, something's wrong before now.

Think: Is the list being filled at all?
Try: Trace potential-target list.
Observe: Has UIDs. So there's something there in the first place.

Think: Ah, so it's removing all potential targets, rather than leaving the Stunners in the list.
Think: It should filter by UnitType. So that's probably what's broken.
Check: Is "Stunner" spelt correctly?
Result: Yes.

Think: So, the UnitType seems not to be "Stunner". So what is it?
Try: Trace UnitType for each check.
Observe: Oh, it's coming up as "Stunner(Clone)".

Think: Odd, I thought V had changed that... Oh, well, I can check for that too.
Change: Accept units with UnitType either "Stunner" or "Stunner(Clone)".
Observe: Seems to work.

...Test a little, put up fixed version.

[close]

[FOXX]

Nice overview of the steps taken.
I can follow the steps but to transfer this to PRPL i just don't have the knowledge.
For the future.

[FOXX]

Update 6-12-2017 [in main post]

Added - Current Map Layout
Added - More Scripts

That's it for today.
Tomorrow i start testplaying.

I'm thinking of posting the testmap or not, want to help me out on this one GM -> it's your map  ;)

[FOXX]

So i have encountered an issue -> the Scripts work as they should only now when an Omni is destroyed the first Script kicks in so there is something wrong.
Going to have to figure this out, can take some time.


Now its almost 1 hour later and i can't figure it out. I played the Map with only this Script running and when the 1st Omni gets destroyed the Script gets activated.
I've used this Script before and this never happened so i think it has to do with the things i added.
If someone could look at this would be very usefull.

Script

Code Select Expand

$PointX:32
$PointY:20
$Range:35
$Msg:"Menu Left"

once
self "main" "NONE" setimage
self 0 setunittakemapspace
self 0 setunitisgoal
self 0 setunitlathetargets
self 0 setunitisenemy

150 ->ListPeriod
30 ->CheckPeriod

<-ListPeriod ->OLTime
<-ListPeriod 2 div ->SLTime

<-CheckPeriod ->OCTime
<-CheckPeriod 2 div ->SCTime

<-PointX 0 lt <-PointY 0 lt and if
currentcoords ->PointY ->PointX
endif

<-Range 1 lt if
1 ->Range
endif

<-PointX <-Range sub ->LowerX
<-PointX <-Range add ->UpperX
<-PointY <-Range sub ->LowerY
<-PointY <-Range add ->UpperY

mapwidth mapheight max 8 div ->ScanRange
mapwidth 8 div ->CenterX
mapheight 8 div ->CenterY
false ->Proximity
endonce

<-OLTime eq0 if
<-CenterX <-CenterY <-ScanRange 1 getallunitsinrange ->UnitList
createlist ->OmniList
<-UnitList getlistcount 0 do
<-UnitList[I] getunittype "Omni" eq if
<-OmniList <-UnitList[I] appendtolist
endif
loop
<-ListPeriod ->OLTime
else
<-OLTime 1 sub ->OLTime
endif

<-SLTime eq0 if
<-CenterX <-CenterY <-ScanRange 1 getallshipsinrange ->ShipList
createlist ->FriendlyList
<-ShipList getlistcount 0 do
<-ShipList[I] getshipisenemy 0 eq if
<-FriendlyList <-ShipList[I] appendtolist
endif
loop
<-ListPeriod ->SLTime
else
<-SLTime 1 sub ->SLTime
endif

<-OCTime eq0 if
<-OmniList getlistcount 0 do
<-OmniList[I] getunitcoords ->OmniY ->OmniX
<-OmniX <-LowerX gt <-OmniX <-UpperX lt and <-OmniY <-LowerY gt and <-OmniY <-UpperY lt and if
true ->Proximity
break
endif
loop
<-CheckPeriod ->OCTime
else
<-OCTime 1 sub ->OCTime
endif

<-SCTime eq0 if
<-FriendlyList getlistcount 0 do
<-FriendlyList[I] getshipcoords ->ShipY ->ShipX
<-ShipX <-LowerX gt <-ShipX <-UpperX lt and <-ShipY <-LowerY gt and <-ShipY <-UpperY lt and if
true ->Proximity
break
endif
loop
<-CheckPeriod ->SCTime
else
<-SCTime 1 sub ->SCTime
endif

<-Proximity if
<-Msg showconversation
AddGameEventAtCell(0 "LAND ALTERNATION BEGINS" 33 40 180) ->gameEvent
300 delay
13 35 3 4 1 setlandbulk
19 35 3 4 1 setlandbulk
26 35 3 4 1 setlandbulk
32 35 3 4 1 setlandbulk
38 35 3 4 1 setlandbulk
44 35 3 4 1 setlandbulk
50 35 3 4 1 setlandbulk
57 35 3 4 1 setlandbulk
AddGameEventAtCell(0 "CORPORATION TEXT ERASED" 34 34 180) ->gameEvent
240 delay
10 24 4 4 1 setlandbulk
18 24 4 4 1 setlandbulk
27 24 4 4 1 setlandbulk
35 24 4 4 1 setlandbulk
44 24 4 4 1 setlandbulk
52 24 4 4 1 setlandbulk
AddGameEventAtCell(0 "ACHIEVEMENTS TEXT ERASED" 34 23 180) ->gameEvent
240 delay
12 15 3 3 1 setlandbulk
19 15 3 3 1 setlandbulk
26 15 3 3 1 setlandbulk
32 15 3 3 1 setlandbulk
39 15 3 3 1 setlandbulk
45 15 3 3 1 setlandbulk
51 15 3 3 1 setlandbulk
57 15 3 3 1 setlandbulk
AddGameEventAtCell(0 "LOAD MISSION TEXT ERASED" 34 14 180) ->gameEvent
240 delay
16 7 4 3 1 setlandbulk
22 7 4 3 1 setlandbulk
29 7 4 3 1 setlandbulk
35 7 4 3 1 setlandbulk
42 7 4 3 1 setlandbulk
48 7 4 3 1 setlandbulk
AddGameEventAtCell(0 "SETTINGS TEXT ERASED" 34 6 180) ->gameEvent
self 0 destroyunit
endif

:awake
self "main" "NONE" setimage
self 0 setunittakemapspace
self 0 setunitisgoal
self 0 setunitlathetargets
self 0 setunitisenemy
iseditmode eq0 if
self 0 setunitselectable
endif

[close]

Edit -> It is Solved -> Thanks Stickman.

[FOXX]

Update 6-14-2017

Added 1 more Script.
Busy with last [small] changes and then Finalize.

[FOXX]

6-15-2017

Map Uploaded !!

[Johnny Haywire]

Wow dude, you put a lot of work and thought into your maps. And the dialogue in this post is pretty funny too... great to know you've got some help in design going on there. I can maybe help with the snack bar, but that's about it.  ;)

And GoodMorning has some pretty funny quips in there too - good stuff  ;D

[FOXX]

Wow dude, you put a lot of work and thought into your maps. And the dialogue in this post is pretty funny too... great to know you've got some help in design going on there. I can maybe help with the snack bar, but that's about it.  ;)

And GoodMorning has some pretty funny quips in there too - good stuff  ;D

Look Good and Play Good, that is what i like my maps to turn out. And with some Maps that  works better then with others.
This Final Map looks totally different then what i had in mind at the start. But that is kind of the Process with almost every Map i make.
Because GM won the AK47 Contest i had to Clarify his thoughts into a Map. Struggled a bit at the start but i'm happy with the result.
He has helped to makes his thoughts clear for His Map. [And the PhantomCoil Script]

A Final Note -> Speaking about Scripts, with Scripts i need a lot of help and PRPL really can give a Map a boost of some sort.
                         I'm sure my maps wouldn't be like they are without help from people on the Forum.
                         They are very helpfull towards each member of the Forum and that also makes Map Making great for me :)

[Johnny Haywire]

Aye, that's a very cool thing indeed  8)